# Maintainer Kamil Bączkowski <me@kavela.ch>

pkgname=pywal-16-colors-git
_gitname=pywal
pkgver=3.3.0.r138.g80a1507
pkgrel=1
pkgdesc="Generate and change color-schemes on the fly, now with 16 colors."
arch=('any')
url="https://git.sheriffmediocre.xyz/pywal"
license=('MIT')
depends=('python')
makedepends=('python-setuptools')
optdepends=('feh: set wallpaper'
            'nitrogen: set wallpaper'
            'python2: reload gtk2 themes on the fly')
provides=("pywal" "pywal-git")
conflicts=("pywal" "pywal-git" "pywal-16-colors")
source=('git+git://git.sheriffmediocre.xyz/pywal')
sha256sums=('SKIP')

pkgver() {
	cd "$srcdir/${_gitname}"
	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	cd "$srcdir/${_gitname}"
	python setup.py build
}

check() {
	cd "$srcdir/${_gitname}"
	python setup.py test
}

package() {
	echo "${conflicts[@]}" > ~/debug
	cd "$srcdir/${_gitname}"
	export PYTHONHASHSEED=0
	python setup.py install --prefix=/usr --root="$pkgdir/" --optimize=1 --skip-build

	install -Dm644 LICENSE.md -t "$pkgdir/usr/share/licenses/${pkgname%-git}"
}

#vim: syntax=sh